import std.stdio;
 
class Sınıf
{
    int i;
}
 
class İşçi
{
    Sınıf nesne;
 
    /* Üzerinde çalışacağı nesneyi kurucuda almak zorunda
     * kalırdı */
    this(Sınıf nesne)
    {
        this.nesne = nesne;
    }
 
    void işle()
    {
        /* Dıştakinin üyelerine nokta ile erişmek zorunda
         * kalırdı */
        writeln(nesne.i);
    }
}
 
void main()
{
    auto nesne = new Sınıf;
 
    /* Hangi nesneyle işleyeceğini kurucuda bildiriyoruz */
    auto işçi = new İşçi(nesne);
    işçi.işle();
}

import std.stdio;
 
class Sınıf
{
    int i;
 
    class İşçi
    {
        /* Burada 'nesne' isminde bir Sınıf değişkeni tutmak
         * gerekmiyor; dıştakine burada otomatik olarak
         * 'this.outer' diye erişilebiliyor. */
 
        /* Kurucu işlev yazmaya gerek yok */
 
        void işle()
        {
            /* Dıştakinin üyelerine nokta ile erişmek zorunda
             * değiliz */
            writeln(i);
 
            /* Bunu yeni hatırladım: i'nin içtekinin bir
             * üyesiyle isim benzerliği olan durumda
             * 'this.outer' diye belirlemek gerekebilir */
 
            writeln(this.outer.i);   // üsttekinin aynısı
        }
    }
}
 
void main()
{
    auto nesne = new Sınıf;
 
    /* Hangi nesneyle işleyeceği kurarken otomatik olarak
     * anlaşılıyor */
    auto işçi = nesne.new İşçi;
    işçi.işle();
}

import std.stdio;
import std.array;
 
struct Eksili(T)
{
    T aralık;
 
    this (T aralık)
    {
        this.aralık = aralık;
    }
 
    @property bool empty()
    {
        return aralık.empty;
    }
 
    @property auto front()
    {
        return -aralık.front;
    }
 
    void popFront()
    {
        aralık.popFront();
    }
}
 
Eksili!T eksili(T)(T aralık)
{
    return Eksili!T(aralık);
}
 
void main()
{
    auto aralık = [ 0, 1, 2 ];
    writeln(eksili(aralık));
}

import std.stdio;
import std.array;
 
auto eksili(T)(T aralık_parametre)
{
    return new class
    {
        T aralık;
 
        this ()
        {
            this.aralık = aralık_parametre;
        }
 
        @property bool empty()
        {
            return aralık.empty;
        }
 
        @property auto front()
        {
            return -aralık.front;
        }
 
        void popFront()
        {
            aralık.popFront();
        }
    };
}
 
void main()
{
    auto aralık = [ 0, 1, 2 ];
    writeln(eksili(aralık));
 
    writeln("tür ismi: ", typeof(eksili(aralık)).stringof);
}

import std.stdio;
 
void main()
{
    auto nesne0 = new class {};
    writeln(typeof(nesne0).stringof);
 
    auto nesne1 = new class {};
    writeln(typeof(nesne1).stringof);
}