D.ershane - Mantıksal İfadeler

Mantıksal İfadeler

Programda asıl işleri ifadeler yaparlar. Programda değer veya yan etki üreten her şeye ifade denir. Aslında oldukça geniş bir kavramdır, çünkü 42 gibi bir tamsayı sabiti bile 42 değerini ürettiği için bir ifadedir. "merhaba" gibi bir dizgi de bir ifadedir, çünkü "merhaba" sabit dizgisini üretir. (Not: Buradaki üretme kavramını değişken tanımlama ile karıştırmayın. Burada yalnızca değer üretmekten söz ediliyor; değişken üretmekten değil. Her değerin bir değişkene ait olması gerekmez.)

writeln gibi kullanımlar da ifadedirler, çünkü yan etkileri vardır: çıkış akımına karakter yerleştirdikleri için çıkış akımını etkilemiş olurlar. Şimdiye kadar gördükleriniz arasından atama işlecini de bir ifade örneği olarak verebiliriz.

İfadelerin değer üretiyor olmaları, onların başka ifadelerde değer olarak kullanılmalarını sağlar. Böylece basit ifadeler kullanılarak daha karmaşık ifadeler elde edilebilir. Örneğin hava sıcaklığını veren bir hava_sıcaklığı() işlevi olduğunu düşünürsek, onu kullanarak şöyle bir çıktı oluşturabiliriz:

writeln("Şu anda hava ", hava_sıcaklığı(), " derece");

O satır toplam dört ifadeden oluşur:

"Şu anda hava " ifadesi
hava_sıcaklığı() ifadesi
" derece" ifadesi
ve o üç ifadeyi kullanan writeln'li ifade

Bu bölümde mantıksal ifadeleri göreceğiz ama daha ileri gitmeden önce en temel işlemlerden olan atama işlecini hatırlayalım.

= (atama işleci): Sağ tarafındaki ifadenin değerini sol tarafındaki ifadeye (örneğin bir değişkene) atar.

hava_sıcaklığı = 23      // hava_sıcaklığı'nın değeri 23 olur

Mantıksal İfadeler

Mantıksal ifadeler Bool aritmetiğinde geçen ifadelerdir. Karar verme düzeneğinin parçası oldukları için bilgisayarları akıllı gösteren davranışların da temelidirler. Örneğin bir programın "eğer girilen yanıt Evet ise dosyayı kaydedeceğim" gibi bir kararında bir mantıksal ifade kullanılır.

Mantıksal ifadelerde yalnızca iki değer vardır: "doğru olmama" anlamını taşıyan false ve "doğruluk" anlamını taşıyan true. Örneğin Türkçe "başkent İstanbul'dur" ifadesinin değeri false, "başkent Ankara'dır" ifadesinin değeri true'dur.

Aşağıdaki örneklerde bir soru ile kullanılan writeln ifadelerini şöyle anlamanız gerekiyor: Eğer sorunun karşısına "true" yazılmışsa evet, "false" yazılmışsa hayır... Örneğin programın çıktısı

Tatlı var: true

olduğunda "evet, tatlı var" demektir. Aynı şekilde

Tatlı var: false

olduğunda "hayır, tatlı yok" demektir. Yani çıktıda "var" göründüğü için "var olduğunu" düşünmeyin; çıktıdaki "... var: false", "yok" anlamına geliyor. Aşağıdaki program parçalarını hep öyle okumanız gerekiyor.

Mantıksal ifadeleri daha ileride göreceğimiz koşullarda, döngülerde, parametrelerde, vs. çok kullanacağız. Programlarda bu kadar çok kullanıldıkları için mantıksal ifadeleri çok iyi anlamak gerekir. Tanımları son derece kısa olduğu için çok da kolaydırlar.

Mantıksal ifadelerde kullanılan mantıksal işleçler şunlardır:

== "Eşit midir" sorusunu yanıtlar. İki tarafındaki ifadelerin değerlerini karşılaştırır ve eşit olduklarında "doğruluk" anlamına gelen true değerini, eşit olmadıklarında da "doğru olmama" anlamına gelen false değerini üretir. Ürettiği değerin türü de doğal olarak bool'dur. Örneğin şöyle iki değişkenimiz olsun:
```
int haftadaki_gün_sayısı = 7;
int yıldaki_ay_sayısı = 12;
```
Onları kullanan iki eşitlik işleci ifadesi ve sonuçları şöyle gösterilebilir:
```
haftadaki_gün_sayısı == 7      // true
yıldaki_ay_sayısı == 11        // false
```
!= "Eşit değil midir" sorusunu yanıtlar. İki tarafındaki ifadeleri karşılaştırır ve == işlecinin tersi sonuç üretir.
```
haftadaki_gün_sayısı != 7      // false
yıldaki_ay_sayısı != 11        // true
```
|| "Veya" anlamındadır. Sol tarafındaki ifadenin değeri true ise hiç sağ taraftaki ifadeyi işletmeden true değerini üretir. Sol taraf false ise sağ taraftakinin değerini üretir. Bu işlem Türkçe veya ifadesine benzer: birincisi, ikincisi, veya ikisi birden true olduğunda true üretir.

Bu işlece verilen iki ifadenin alabileceği olası değerler ve sonuçları şöyledir:

Sol ifade Sağ ifade Sonuç

false false false

false true true

true false (bakılmaz) true

true true (bakılmaz) true
```
import std.stdio;

void main()
{
    /*
      false, "doğru olmama" anlamına geldiği için
      burada "yok"u temsil etsin

      true, "doğru olma" anlamına geldiği için
      burada "var"ı temsil etsin
     */
    bool baklava_var = false;
    bool kadayıf_var = true;

    writeln("Tatlı var: ", baklava_var || kadayıf_var);
}
```
Yukarıdaki programdaki || işlecini kullanan ifade, en az bir true değer olduğu için true değerini üretir.
&& "Ve" anlamındadır. Sol tarafındaki ifadenin değeri false ise hiç sağ taraftaki ifadeyi işletmeden false değerini üretir. Sol taraf true ise sağ taraftakinin değerini üretir. Bu işlem Türkçe ve ifadesine benzer: birincisi ve ikincisi true olduğunda true üretir.

Sol ifade Sağ ifade Sonuç

false false (bakılmaz) false

false true (bakılmaz) false

true false false

true true true
```
writeln("Baklava yiyeceğim: ",
        baklava_yemek_istiyorum && baklava_var);
```

Sol ifade	Sağ ifade	Sonuç
false	false	false
false	true	true
true	false (bakılmaz)	true
true	true (bakılmaz)	true

Sol ifade	Sağ ifade	Sonuç
false	false (bakılmaz)	false
false	true (bakılmaz)	false
true	false	false
true	true	true

Not: || ve && işleçlerinin bu "sağ tarafı ancak gerektiğinde" işletme davranışları işleçler arasında çok nadirdir, ve bir de şimdilik sonraya bırakacağımız ?: işlecinde vardır. Diğer işleçler bütün ifadelerinin değerlerini her zaman için hesaplarlar ve kullanırlar.

^ "Yalnızca birisi mi" sorusunu yanıtlar. İki ifadeden ya biri ya öbürü true olduğunda (ama ikisi birden değil) true değerini üretir.

Sol ifade Sağ ifade Sonuç

false false false

false true true

true false true

true true false

Örneğin ancak ve ancak bir arkadaşımın geldiğinde tavla oynayacağımı, aksi taktirde onlarla başka bir şey yapacağımı düşünürsek; onların gelip gelmeme durumlarına göre tavla oynayıp oynamayacağımı şöyle hesaplayabiliriz:
```
writeln("Tavla oynayacağım: ", ahmet_burada ^ barış_burada);
```
< "Küçük müdür" sorusunu yanıtlar. Sol taraf sağ taraftan küçükse (veya sıralamada önceyse) true, değilse false değerini üretir.
```
writeln("Yendik: ", yediğimiz_gol < attığımız_gol);
```
> "Büyük müdür" sorusunu yanıtlar. Sol taraf sağ taraftan büyükse (veya sıralamada sonraysa) true, değilse false değerini üretir.
```
writeln("Yenildik: ", yediğimiz_gol > attığımız_gol);
```
<= "Küçük veya eşit midir" sorusunu yanıtlar. Sol taraf sağ taraftan küçük (veya sıralamada daha önce) veya ona eşit olduğunda true üretir. > işlecinin tersidir.
```
writeln("Yenilmedik: ", yediğimiz_gol <= attığımız_gol);
```
>= "Büyük veya eşit midir" sorusunu yanıtlar. Sol taraf sağ taraftan büyük (veya sıralamada daha sonra) veya ona eşit olduğunda true üretir. < işlecinin tersidir.
```
writeln("Yenmedik: ", yediğimiz_gol >= attığımız_gol);
```
! "Tersi" anlamındadır. Diğer mantıksal işleçlerden farklı olarak tek bir ifade ile çalışır ve sağ tarafındaki ifadenin değerinin tersini üretir: true ise false, false ise true.
```
writeln("Bakkala gideceğim: ", !ekmek_var);
```

Sol ifade	Sağ ifade	Sonuç
false	false	false
false	true	true
true	false	true
true	true	false

İfadeleri Gruplamak

İfadelerin hangi sırada işletilecekleri, gerektiğinde parantezlerle belirtilir. Karmaşık ifadelerde önce parantez içindeki ifadeler işletilir ve onların değeri dıştaki işleçle kullanılır. Örneğin "kahve veya çay varsa ve yanında da baklava veya kadayıf varsa keyfim yerinde" gibi bir ifadeyi şöyle hesaplayabiliriz:

writeln("Keyfim yerinde: ",
        (kahve_var || çay_var) && (baklava_var || kadayıf_var));

Kendimiz parantezlerle gruplamazsak, ifadeler D dilinin kuralları ile belirlenmiş olan önceliklere uygun olarak işletilirler. && işlecinin önceliği de || işlecinden daha yüksek olduğu için, yukarıdaki mantıksal ifadeyi gruplamadan şöyle yazarsak

writeln("Keyfim yerinde: ",
        kahve_var || çay_var && baklava_var || kadayıf_var);

işlem öncelikleri nedeniyle şunun eşdeğeri olarak işletilir

writeln("Keyfim yerinde: ",
        kahve_var || (çay_var && baklava_var) || kadayıf_var);

ve tamamen farklı anlamda bir ifadeye dönüşür: "kahve varsa, veya çay ve baklava varsa, veya kadayıf varsa; keyfim yerinde".

Bütün işleçlerin işlem önceliklerini hemen hemen hiçbir programcı ezbere bilmez. O yüzden, gerekmese bile parantezler kullanarak hangi ifadeyi kurmak istediğinizi açıkça belirtmek kodun anlaşılırlığı açısından çok yararlıdır.

Girişten `bool` Okumak

Yukarıdaki örneklerdeki bütün bool ifadeler çıkışa "false" veya "true" dizgileri olarak yazdırılırlar. Bunun karşıtı doğru değildir: girişten okunan "false" ve "true" dizgileri otomatik olarak false ve true değerlerine dönüştürülmezler. O yüzden, girişten gelen kelimeyi önce bir dizgi olarak okumamız, ve sonra ona bakarak bir bool değere dönüştürmemiz gerekir.

Aşağıdaki programı denerken girişten "false" ve "true" girebilmenizi istiyorum. Böylece bu derste anlatılanları aynen deneyebileceksiniz. Bunun olabilmesi için, derslerin başında planladığım yoldan sapacak ve istemeyerek henüz anlatmadığım kodlar göstereceğim. Girişten gelen "false" dizgisini false değerine, "true" dizgisini de true değerine dönüştüren bir işlev kullanacağım. Bu işlev, std.conv modülünde tanımlanmış olan to'dan yararlanacak. ("false" veya "true"dan başka bir dizgi girdiğinizde ConvException hatası atılır.)

Aşağıdaki programlardaki main'ler içinde anlaşılmaz bir taraf olmadığını umuyorum. Ama girişten_bool_oku() işlevinde henüz görmediğiniz olanaklar kullanılıyor; içine açıklamalar koydum ama isterseniz o işlevi şimdilik tamamen gözardı da edebilirsiniz.

Problemler

Sayıların büyüklüğü ve küçüklüğü ile ilgili olan <, > vs. işleçleri bu derste tanıdık. Bu işleçler içinde "arasında mıdır" sorusunu yanıtlayan işleç bulunmaz. Yani verilen bir sayının iki değer arasında olup olmadığını hesaplayan işleç yoktur. Bir arkadaşınız bunun üstesinden gelmek için şöyle bir program yazmış olsun. Bu programı derlemeye çalışın ve derlenemediğini görün:

import std.stdio;

void main()
{
    int sayı = 15;

    writeln("Arasında: ", 10 < sayı < 20); // ← derleme HATASI
}

Derleme hatasını gidermek için bütün ifadenin etrafında parantez kullanmayı deneyin:

writeln("Arasında: ", (10 < sayı < 20));

Yine derlenemediğini görün.

Aynı arkadaşınız hatayı gidermek için bir şeyler denerken derleme hatasının gruplama ile giderildiğini farketsin:

writeln("Arasında: ", (10 < sayı) < 20);

Bu sefer programın beklendiği gibi çalıştığını ve "true" yazdığını gözlemleyin. Ne yazık ki o çıktı yanıltıcıdır çünkü programda gizli bir hata bulunuyor. Hatanın etkisini görmek için 15 yerine bu sefer 20'den büyük bir değer kullanın:

    int sayı = 21;

O değer 20'den küçük olmadığı halde programın yine de "true" yazdırdığını görün.

İpucu: Mantıksal ifadelerin değerlerinin bool türünde olduklarını hatırlayın. Bildiğiniz bool değerlerin 20 gibi bir sayıdan küçük olması gibi bir kavram tanımadık.

D'de "arasında mıdır" sorusunu yanıtlayan mantıksal ifadeyi şu şekilde kodlamamız gerekir: alt sınırdan büyüktür ve üst sınırdan küçüktür. Programdaki ifadeyi o şekilde değiştirin ve artık çıktının beklendiği gibi "true" olduğunu görün. Ayrıca, yazdığınız ifadenin sayı'nın başka değerleri için de doğru çalıştığını denetleyin. Örneğin, sayı 50 veya 1 olduğunda sonuç "false" çıksın; 12 olduğunda "true" çıksın.
Plaja ancak iki koşuldan birisi gerçekleştiğinde gidiyor olalım:

Mesafe 10'dan az (kilometre varsayalım) ve yeterince bisiklet var
Kişi sayısı 5 veya daha az, arabamız var, ve ehliyetli birisi var

Aşağıdaki programdaki mantıksal ifadeyi bu koşullar sağlandığında "true" yazdıracak şekilde kurun. Programı denerken "... var mı?" sorularına "false" veya "true" diye yanıt verin:

import std.stdio;
import std.conv;
import std.string;

void main()
{
    write("Kaç kişiyiz? ");
    int kişi_sayısı;
    readf(" %s", &kişi_sayısı);

    write("Kaç bisiklet var? ");
    int bisiklet_sayısı;
    readf(" %s", &bisiklet_sayısı);

    write("Mesafe? ");
    int mesafe;
    readf(" %s", &mesafe);

    bool araba_var = girişten_bool_oku("Araba var mı? ");
    bool ehliyet_var = girişten_bool_oku("Ehliyet var mı? ");

    /*
      Buradaki true'yu silin ve yerine sorudaki koşullardan
      birisi gerçekleştiğinde true üreten bir mantıksal ifade
      yazın:
     */
    writeln("Plaja gidiyoruz: ", true);
}

/*
  Bu işlevde henüz göstermediğim olanaklar kullanılıyor. Bu
  yüzden, aslında gerekmeyen açıklamalar da ekledim.
 */
bool girişten_bool_oku(string mesaj)
{
    // Mesajı yazdır
    writef(mesaj ~ "(false veya true) ");

    // Girilen satırı bir dizgiye oku
    string giriş;
    while (giriş.length == 0) {
        giriş = chomp(readln());
    }

    // O dizgiden bir bool değer üret
    bool dönüştürülen_değer = to!bool(giriş);

    // Üretilen değeri işlevi çağırana döndür
    return dönüştürülen_değer;
}

Çeşitli değerler girin, ve yazdığınız ifadenin her durumda doğru çalıştığını denetleyin: koşullara uyduğunda "true", uymadığında "false" yazsın.

... çözümler

[ ↢ Geri ] [ İleri ↣ ]

Mantıksal İfadeler

Mantıksal İfadeler

İfadeleri Gruplamak

Girişten bool Okumak

Problemler

Girişten `bool` Okumak